Checking  the algebra of the phase-space point operators.  CAH, 16.i.24.

Clear["Global`*"];

Set  up the definitions.

ω=Exp[2 I π/3];
X={{0,0,1},{1,0,0},{0,1,0}};
Z={{1,0,0},{0,ω,0},{0,0,(ω^2)}};
T[a_,ap_]:=(ω^(-2 a ap)) MatrixPower[Z,a].MatrixPower[X,ap];

Check  the various identities that these should obey.

(ω^3)
MatrixPower[X,3]//MatrixForm
MatrixPower[Z,3]//MatrixForm
ConjugateTranspose[X].X//MatrixForm
ConjugateTranspose[Z].Z//MatrixForm

Look  at some examples of Pauli string operators for a single site.

Table[T[i,j]//MatrixForm,{i,0,2},{j,0,2}]

Define  the sum of Pauli strings and check its form.

S=Simplify[Sum[T[i,j],{i,0,2},{j,0,2}]];

S//MatrixForm

Define  the  phase space point operators and check their form.

A[b_,bp_]:=Simplify[(1/3) T[b,bp].S.ConjugateTranspose[T[b,bp]]];

Table[A[i,j]//MatrixForm,{i,0,2},{j,0,2}]

Check  the  trace identity.

Table[FullSimplify[Tr[A[IntegerDigits[i,3,2][[1]],IntegerDigits[i,3,2][[2]]].A[IntegerDigits[j,3,2][[1]],IntegerDigits[j,3,2][[2]]]]],{i,0,8},{j,0,8}]//MatrixForm